C Mixture cleaning
C v1.00

C The flow valve with V12 needs to be adjusted properly
C Suggested: one turn more closed than normal
C Also the script requires the mixture to be fully 
C  in the dumps at the start

C var1 is initial p5
C var2 is cycle initial p5
C var3 is the number of cycles completed
C var4 is cycle initial p2
C var5 is cycle initial time

START

STATE 1
SET_STATE 100

STATE 100
IF (turbo1==1)||(scroll2==1)||(v15==1)||(v17==1)||(v18==1)||(v1==1)
ERROR Stop turbo and disconnect from aux
C Stop turbo and disconnect from aux
ELSE
SET_STATE 101
ENDIF

STATE 101
OFF_ALL
SET_STATE 102

STATE 102
ON scroll1
SET_STATE 103
WAIT 5

STATE 103 Open Valves
C Adjust Valves
ON v2
ON v3
ON v4
SET_STATE 104
WAIT 1

STATE 104 Check Pressures
IF (p2>0.2)||(p3>2)
ERROR Remove mixture from system first
C Remove mixture from system first
ELSE
SET_STATE 200
ENDIF

C Cleaning sequence (x5 see state 265)
STATE 200 Initialize cleaning
SET var1=p5
SET var3=0
SET_STATE 201

STATE 201 Cycle Start
OFF v7
SET_STATE 202
WAIT 1

STATE 202
ON v9
C Wait for mixture to cooldown in trap
SET_STATE 203
WAIT 30

STATE 203
ON v7
SET_STATE 205
WAIT 60

STATE 205
SET var2=p5
SET var4=p2
SET var5=time
ON v12
SET_STATE 210
WAIT 1

STATE 210 Rate checks manual valve closed
IF p5<400
OFF  v12
ERROR Manual dump valve is probably closed
ELSE
SET_STATE 211
ENDIF

STATE 211 Rate checks trap plugged
IF p4>(p2+50)
OFF v12
ERROR Traps are probably plugged. Clean them!
ELSE
SET_STATE 212
ENDIF

STATE 212 Rate checks p2 increase pressure
C test for first minute
IF (p2>p5)&&((time-var5)<60)
OFF v12
ERROR Flow valve proabably too open. p2 increases too rapidly.
ELSE
SET_STATE 213
ENDIF

STATE 213 Rate checks p2 increase rate
C Limit of 80 mbar/min after first 30s
IF ((time-var5)>30)&&(((p2-var4)/(time-var5)*60)>80)
OFF v12
ERROR Flow valve proabably too open. p2 increases too rapidly.
ELSE
SET_STATE 214
ENDIF

STATE 214 Rate checks p5 decrease rate
C Limit of 40 mbar/min after first 30s
IF ((time-var5)>30)&&(((var2-p5)/(time-var5)*60)>40)
OFF v12
ERROR Flow valve proabably too open or Manual dump valve closed. p5 goes down too fast.
ELSE
SET_STATE 240
ENDIF

STATE 240 Check End of cycle
IF p2>800
SET_STATE 250
ELSE
C Continue Checking
SET_STATE 210
WAIT 5
ENDIF

STATE 250
OFF v12
OFF v9
SET_STATE 255
WAIT 1

STATE 255
ON v13
SET_STATE 260
WAIT 10

STATE 260 Pump mixture back into dumps
ON v10
SET_STATE 270

STATE 270 Check pumping
IF p2<0.4
OFF v10
OFF v13
SET var3=(var3+1)
SET_STATE 275
WAIT 15
ELSE
SET_STATE 270
WAIT 15
ENDIF

STATE 275 Iteration Check
IF var3<5
SET_STATE 201
ELSE
SET_STATE 300
ENDIF

STATE 300
ON v10
ON v13
ON v1
SET_STATE 310
WAIT 30

STATE 310
ON turbo1
OFF v2
SET_STATE 500

STATE 500
STOP

END